Menyesuaikan Gradle Project Lama dengan Android Studio Terbaru

Untuk Anda yang baru mencoba Android Studio terbaru (Bumblee bee ke atas) pasti melihat ada yang berbeda dengan code starter. Terutama di bagian build.gradle. Ini adalah contoh format yang lama.

buildscript {
    repositories {
        google()
        mavenCentral()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:7.2.1'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:1.7.0"
        classpath 'androidx.navigation:navigation-safe-args-gradle-plugin:2.5.0'
        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}
allprojects {
    repositories {
        google()
        mavenCentral()
    }
}
task clean(type: Delete) {
    delete rootProject.buildDir
}

Lalu, bagaimana format yang baru? Yang baru lebih clean dan fresh. Bentuknya seperti ini.

buildscript {
    dependencies {
        classpath "androidx.navigation:navigation-safe-args-gradle-plugin:2.5.1"
    }
}
plugins {
    id 'com.android.application' version '7.2.1' apply false
    id 'com.android.library' version '7.2.1' apply false
    id 'org.jetbrains.kotlin.android' version '1.7.10' apply false
}
task clean(type: Delete) {
    delete rootProject.buildDir
}

Jika diperhaikan buildScript repositories sudah tidak ada, bahkan Anda bisa menghapusnya jika tidak menggunakan SafeArg. Lalu, di mana posisi repository-nya?

Jawabannya ada di file setting.gradle seperti ini.

pluginManagement {
    repositories {
        gradlePluginPortal()
        google()
        mavenCentral()
    }
}
dependencyResolutionManagement {
    repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)
    repositories {
        google()
        mavenCentral()
    }
}
include ':app'
rootProject.name='MyNavigation'

Jadi, jika Anda ingin mengubah ke format terbaru, jangan lupa menambahkan kode di setting.gradle juga ya..

Sekian dan semoga bermanfaat

Keep smiling, because life is a beautiful thing and there’s so much to smile about.